ZSH: делаем второй шаг

В предыдущем посте было немало сказано о вкусностях, которые сулит пользователю Z-Shell. Но та статья имела вводной характер, её призвание — заинтересовать потенциального пользователя любопытными возможностями. Свою задачу она выполнила на целых 200%, поэтому по требованию читателей я расскажу о том, как на практике юзать вкусности zsh.

Обсуждать каждую используемую мной возможность было бы очень долго и довольно скучно — могу поспорить, читателям не терпится перейти от простого чтения к правке своих .zshrc. По этой причине статья будет построена на цитировании наиболее интересных кусков моего конфига с добавлением некоторых пояснений.

Автодополнение

Автодополнение — это то, что чаще всего упоминается в разговоре о zsh. Включить его очень просто:

autoload -Uz compinit && compinit

Поведение этой функции можно конфигурировать очень долго, но т.к. я этим пока не занимался — меня вполне устраивают дефолтные настройки — ничего более подробного я не расскажу.

История

# файл истории
HISTFILE=~/.history
# кол-во команд, хранимых шеллом в текщей сессии
HISTSIZE=10240
# кол-во команд, которые будут сохранены в истории
SAVEHIST=8192
# все работающие копии zsh будут иметь одинаковую историю
# не беспокойтесь — команды вроде «!» (повтор последней команды) будут использовать
#  только историю текущего шелла
setopt SHARE_HISTORY
# при добавлении в историю новой команды все её дупликаты будут удалены, а команда
#  будет помещена в конец
setopt HIST_IGNORE_ALL_DUPS
# не сохранять команды, начинающиеся с пробела
# очень удобно, если вы вынуждены указать в командной строке имя пользователя,
#  пароль или другую конфиденциальную информацию
setopt HIST_IGNORE_SPACE
# команды «history» и «fc» в историю заноситься не будут
setopt HIST_NO_STORE

Приглашение командной строки (prompt)

В ZSH, в отличие от bash’а, prompt’ов два — левый и правый. Лично я считаю очень удачным вариантом такие настройки:

# левое приглашение — «%» для обычного юзера и «#» — для рута
PROMPT="%# "
# правое приглашение — путь к текущей директории (от ~, если вы где-то в домашней
#  директории, или от /, если вы пошли бродить по системе), отображаемый зелёным
#  цветом
RPROMPT="%{$fg[green]%}%~%{$reset_color%}"

Хорошей альтернативой ручному заданию prompt’а является использование promptinit. Откройте zsh и наберите следующее:

% autoload promptinit
% promptinit
% prompt -p

По экрану быстро промелькнёт около 20 вариантов приглашений, которые вы можете использовать. Если какая-то из тем вам понравилась, наберите:

% prompt имя_темы

и тема будет применена. Подтвердить, что вы хотите использовать именно эту тему, можно следующей командой:

% prompt -s имя_темы

Мой zsh (версии 4.3.6) пока что не поддерживает сохранение, но если вы столкнулись с такой же ситуацией — не расстраивайтесь. Вам достаточно самостоятельно закомментировать вышеприведённые PROMPT и RPROMPT (если вы добавили их в конфиг, конечно) и вместо них написать следующее:

autoload -U promptinit && promptinitprompt имя_понравившейся_темы

Алиасы

Казалось бы, алиасы — простая сущность, что же здесь можно было улучшить? Тем не менее, авторы zsh нашли что добавить к привычной функциональности.

В прошлой статье упоминалось автоматическое исправление команд — например, если вы набрали «aptitde install пакет», шелл предложит вам заменить aptitde на aptitude. Иногда эта возможность может обернуться лихом, пытаясь заменить какие-то команды (mc на mv или наоборот). Если такое случается, добавьте соответствующий алиас:

alias mc="nocorrect mc"

Ключевым здесь является слово nocorrect — оно указывает zsh’у ни в коем случае не исправлять «mc».

Вторым расширением алиасов, которое я оценил лишь недавно, являются так называемые суффиксальные алиасы. Они призваны упростить работу с файлами. Рассмотрим пример:

alias -s pdf=evince
alias -s djvu=evince
alias -s fb2=fbless

Думаю, некоторые читатели уже догадались — суффиксальные алиасы служат для установки соответствия между расширениями файлов и программами. Например, теперь мне не надо писать «evince file.pdf» — я набираю только «file.pdf», а суффиксальный алиас «разворачивает» это в «evince file.pdf». Эта штука реально экономит время и силы.

Ещё одним улучшением в алиасах стали глобальные алиасы, но я с ними пока не разбирался, так что просто отошлю вас к заметке muhas’а — он описал всё достаточно подробно. Кстати, именно из этого его поста я узнал про суффиксальные и глобальные алиасы.

Функции

Вот мы и подошли к функциям — довольно обыденной вещи, которую, тем не менее, тоже нафаршировали вкусностями :) Одна из них — это функции precmd и preexec. Первая вызывается перед выводом prompt, вторая — перед выполнением какой-либо команды. Я это использовал для того, чтобы добавлять в заголовок urxvt имя запущенной программы

case $TERM in
  xterm* | rxvt*)
    # precmd вызывается непосредственно перед выводом prompt
    precmd() {
      print -Pn "\e]0;zsh\a"
    }

    # preexec вызывается перед выполнением команды
    # $1 — имя команды (точнее, вся команда со всеми переданными параметрами)
    # sed используется для «отрезания» от команды параметров
    preexec() {
      print -Pn "\e]0;`echo $1 | sed -r 's/^([^[:space:]]+).*/\1/'`\a"
    }
  ;
esac

Определения функций заключены в case, срабатывающий только в иксовых терминалах — если бы эти функции выполнялись в tty, перед выводом приглашения и перед выполнением команды вы получали бы на экране всякую чепуху.

Ещё одна функция, которой я хотел бы с вами поделится — это lcd:

function lcd() {cd "$1" && ls}

Лично мне она экономит довольно много времени, т.к. обычно после перехода в директорию я вызываю ls.

Miscellaneous

Напоследок мне осталось рассказать о всяких незначительных опциях, которые нельзя ни выбросить, ни отнести к какому-то из вышеприведённых разделов.

# переходить в директорию даже если пользователь не ввёл cd в начале, но набрал
#  верный путь
setopt AUTO_CD
# по возможности исправлять команды
setopt CORRECT
# цвета для ls
# при переносе на другую машину не забудьте захватить мой ~/.dir_colors, в котором
#  переопределён цвет для директорий
eval `dircolors ~/.dir_colors`
zstyle ':completion:*:default' list-colors ${(s.:.)LS_COLORS}
# Включение поддержки выражений вроде «{1-3}» или «{a-d}» — они будут разворачиваться
#  в «1 2 3» и «a b c d» соответственно
setopt BRACECCL
# загрузка системы помощи
# для удобства использования можно добавить алиас help="run-help"
autoload run-help

Требуется сделать небольшое примечание касательно цветов для ls: мой ~/.dir_colors вы можете получить здесь, почитать о том, что же сподвигло меня менять умолчальные настройки — тут.

Собственно, на этом разговор об используемых мною вкусностях zsh можно закончить. Советую заглянуть в блог muhas’а, там довольно много записей с тегом zsh.

P.S. В процессе экспериментов вам обязательно захочется сразу применять изменённый .zshrc. Для этого после редактирования и сохранения изменений вам достаточно набрать в терминале следующее:

source .zshrc

Comments (migrated from Blogger)

e   -- extract files to current directory
l   -- list archive
lb  -- list archive (bare format)
lt  -- list archive (technical format)
p   -- print file to stdout
t   -- test archive files
v   -- verbosely list archive
vb  -- verbosely list archive (bare format)
vt  -- verbosely list archive (technical format)
x   -- extract files with full path

$ cclive http://www.youtube.com/watch?v=HEheh1BH34Q
zsh: no matches found: http://www.youtube.com/watch?v=HEheh1BH34Q 

#ssh bla@bla
#ssh bla@foo